root/branches/hackathon-mt/MT-Plagger/MT-Plagger.pl

# Plagger plugin for Movable Type
# Author: Six Apart (http://www.sixapart.com)
# Released under the Artistic License
#
# $Id$

package MT::Plugin::Plagger;
use strict;
use MT::Plugin;
use base qw(MT::Plugin);

our $VERSION = 0.1;

use MT;
my $plugin = __PACKAGE__->new({
    name => "MT-Plagger",
    version => $VERSION,
    description => "Bootstrapt Plagger process out of newly created or updated MT::Entry and MT::Blog",
    author_name => "Six Apart, Ltd.",
    author_link => "http://www.sixapart.com/",
    settings => new MT::PluginSettings([
        ['plagger_config'],
    ]),
    config_template => 'config.tmpl',
#    l10n_class => 'GoogleSearch::L10N',
});
MT->add_plugin($plugin);
MT->add_callback('CMSPostSave.entry', 9, $plugin, \&bootstrap_plagger);

use MT::Tag;
use MT::ObjectTag;

use Encode;
use Plagger;
use Plagger::Entry;
use Plagger::Feed;

sub bootstrap_plagger {
    my($eh, $app, $e, $old) = @_;

    return if $e->status != MT::Entry::RELEASE;

    my $config = $plugin->get_config_hash('blog:' . $e->blog_id);
    my $context = Plagger->new(config => \$config->{plagger_config});

    my $blog = $e->blog;

    my $feed = Plagger::Feed->new;
    $feed->title( decode_utf8($blog->name) );
    $feed->description( decode_utf8($blog->description) );
    $feed->link( $blog->site_url );
    $feed->language( $blog->language );
    $feed->updated( MT::Util::ts2iso($e->created_on) );

    my $entry = Plagger::Entry->new;
    $entry->title( decode_utf8($e->title) );
    $entry->author( decode_utf8($e->author->name) );

    $entry->tags( _tags_for($e) );
    $entry->link( $e->permalink );
    $entry->summary( $e->excerpt );

    $entry->body( _apply_text_filter($e, $e->text) . _apply_text_filter($e, $e->text_more) );
    $entry->date( MT::Util::ts2iso($e->created_on) );

    $feed->add_entry($entry);

    $context->subscription->add($feed);
    $context->update->add($feed);

    $context->run_with_feeds;
}

sub _apply_text_filter {
    my($e, $text) = @_;
    return '' unless defined $text;

    my $convert_breaks = defined $e->convert_breaks
        ? $e->convert_breaks : $e->blog->convert_paras;
    if ($convert_breaks) {
        my $filters = $e->text_filters;
        push @$filters, '__default__' unless @$filters;
        $text = MT->apply_text_filters($text, $filters);
    }

    return $text;
}

sub _tags_for {
    my $e = shift;

    my @tags = MT::Tag->load(undef, {
        sort => 'name',
        join => [ 'MT::ObjectTag', 'tag_id', {
            object_id => $e->id,
            blog_id   => $e->blog_id,
            object_datasource => MT::Entry->datasource,
        } , {
            unique => 1,
        } ],
    });

    return map $_->name, @tags;
}

1;