root/branches/feature-server/plagger/lib/Plagger/Plugin/Store/DBIC.pm

package Plagger::Plugin::Store::DBIC;
use strict;
use warnings;
use base qw/Plagger::Plugin Class::Accessor::Fast/;

use Algorithm::Diff;
use UNIVERSAL::require;

our $VERSION = '0.02';

__PACKAGE__->mk_accessors(qw/schema/);

=head1 NAME

Plagger::Plugin::Store::DBIC - Store feeds in DBI

=head1 SYNOPSIS

    $ sqlite3 /path/to/plagger.db < sql/plagger.sqlite.sql

    - module: Store::DBIC
      config:
        schema_class: Plagger::Schema::SQLite
        connect_info: [ 'dbi:SQLite:/path/to/plagger.db', ]

=head1 DESCRIPTION

Store DBI

=head1 METHODS

=head2 register

=cut

sub register {
    my ( $self, $c ) = @_;

    unless ( $self->conf->{schema_class} and $self->conf->{connect_info} ) {
        $c->error('schema_class and connect_info are required');
    }

    $self->conf->{schema_class}->require
        or $c->error(
        qq/Can't load schema class "@{[ $self->conf->{schema_class} ]}", $@/);

    $self->schema( $self->conf->{schema_class}
            ->connect( @{ $self->conf->{connect_info} } ) );

    $c->register_hook( $self, 'publish.feed' => \&store, );
}

=head2 store

=cut

sub store {
    my ( $self, $c, $args ) = @_;

    # feed
    my $feed = $self->schema->resultset('Feed')->find_or_new(
        {   link => $args->{feed}->link,
#            type => $args->{feed}->type,
        }
    );

    my $data;
    for my $attr (qw/url title description language author updated/) {
        $data->{$attr} = $args->{feed}->$attr if defined $args->{feed}->$attr;
    }

    # xxx
    $data->{image} = $args->{feed}->image->{url} if $args->{feed}->image;
    $data->{updated} ||= eval { $args->{feed}->entries->[0]->date } || Plagger::Date->now;

    for my $attr (keys %$data) {
        $feed->$attr( $data->{$attr} ) if !$feed->$attr or $feed->$attr ne $data->{$attr};
    }
    $feed->insert_or_update if !$feed->in_storage or $feed->is_changed;

    # feed meta
    $feed->metas->delete_all; # need more hack
    for my $k ( keys %{ $args->{feed}->meta } ) {
        $feed->add_to_metas( { keyid => $k, value=> $args->{feed}->meta->{$k} } );
    }

    # feed tag
    my @feed_tags = map { $_->name } $feed->tags;
    my $feed_diff = $self->diff( \@feed_tags, $args->{feed}->tags );

    $feed->tags( { name => $feed_diff->{deleted} } )->delete_all
        if @{ $feed_diff->{deleted} };

    for ( @{ $feed_diff->{added} } ) {
        $feed->add_to_tags( { name => $_ } );
    }


    # entry
    for my $feed_entry ( @{ $args->{feed}->entries } ) {
        my $entry = $self->schema->resultset('Entry')->find_or_new({
            feed => $feed->id,
            link => $feed_entry->link,
        });

        for my $attr (qw/title author summary date body rate/) {    # todo: icon
            $entry->$attr( $feed_entry->$attr )
                if defined $feed_entry->$attr && (!$entry->$attr or $entry->$attr ne $feed_entry->$attr);
        }
        $entry->insert_or_update if $entry->is_changed;

        # meta
        $entry->metas->delete_all;
        for my $k ( keys %{ $feed_entry->meta } ) {
            $entry->add_to_metas(
                { keyid => $k, value => $feed_entry->meta->{$k}, } );
        }

        # tag
        my @entry_tags = map { $_->name } $entry->tags;
        my $entry_diff = $self->diff( \@entry_tags, $feed_entry->tags );

        $entry->tags( { name => $entry_diff->{deleted} } )->delete_all
            if @{ $entry_diff->{deleted} };

        for ( @{ $entry_diff->{added} } ) {
            $entry->add_to_tags( { name => $_ } ) if $entry->id; # xxx
        }
    }
}

=head2 diff

=cut

sub diff {
    my ( $self, $old, $new ) = @_;

    my $result = {
        added   => [],
        deleted => [],
    };

    my $diff = Algorithm::Diff->new( $old, $new );
    while ( $diff->Next ) {
        next if $diff->Same;

        if ( !$diff->Items(2) ) {
            push @{ $result->{deleted} }, $diff->Items(1);
        }
        else {
            push @{ $result->{added} }, $diff->Items(2);
        }
    }

    $result;
}

=head1 AUTHOR

Daisuke Murase <typester@cpan.org>

=head1 COPYRIGHT

This program is free software; you can redistribute
it and/or modify it under the same terms as Perl itself.

The full text of the license can be found in the
LICENSE file included with this module.

=cut

1;