Ticket #171: LivedoorWeather.pm.txt

package Plagger::Plugin::Filter::LivedoorWeather;
use strict;
use base qw(Plagger::Plugin);

sub register {
    my($self, $context) = @_;

    $context->register_hook(
        $self,
        'update.feed.fixup' => \&filter,
    );
}

sub filter {
    my($self, $context, $args) = @_;

    return unless $args->{feed}->url =~ m|^http://weather.livedoor.com/forecast/rss/|;
    $context->log(debug => "Found LivedoorWeather feed " . $args->{feed}->url);

    for my $entry ($args->{feed}->entries) {

        # strip PR entry
        if (grep { $_ eq 'PR'} @{$entry->tags}) {
            $context->log(info => "Strip PR entry " . $entry->link);
            $args->{feed}->delete_entry($entry);
            next;
        }

        # fix title
        $entry->title(join(' - ', (split ' - ', $entry->title)[1..2]));

        # replace pubDate with forcast day
        my ($year, $month, $day) = $entry->link =~ m|(\d{4})(\d{2})(\d{2})$|;
        $entry->date->set(
            year  => $year,
            month => $month,
            day   => $day,
        );

        # add link to the entry body
        $entry->body($entry->body.' '.$entry->link);
    }
}

1;